0

Description

"Hook up callables to strings. Arguments are automatically detected, I trust you.\r\n\r\n```\r\nfunc _ready() -> void:\r\n EventBus.subscribe(\"event_plain\", self , self.event_plain)\r\n EventBus.subscribe(\"event_var\", self , self.event_var)\r\n EventBus.subscribe(\"event_vars\", self , self.event_vars)\r\n print(\"===\")\r\n EventBus.emit(\"event_plain\")\r\n EventBus.emit(\"event_var\", \"Hello, var!\")\r\n EventBus.emit(\"event_vars\", [\"Hello,\", \"vars!\"])\r\n EventBus.unsubscribe(\"event_plain\", self)\r\n EventBus.unsubscribe(\"event_var\", self, self.event_var)\r\n print(\"---\")\r\n EventBus.emit(\"event_plain\")\r\n EventBus.emit(\"event_var\", \"Hello, var!\")\r\n EventBus.emit(\"event_vars\", [\"Hello,\", \"vars!\"])\r\n\r\nfunc event_plain() -> void:\r\n print(\"Hello, World!\")\r\nfunc event_var(str: String) -> void:\r\n print(str)\r\nfunc event_vars(first: String, second: String) -> void:\r\n prints(first, second)\r\n```\r\n\r\nThe above script will print out:\r\n```\r\n===\r\nHello, World!\r\nHello, var!\r\nHello, vars!\r\n---\r\nHello, vars!\r\n```"

Main code

extends Node

# Dictionary to hold event listeners
var listeners : Dictionary = {}

# Register a listener for a specific event
func subscribe(event_name: String, listener: Object, method: Callable) -> void:
  # Clean up after objects
  if listener is Node:
    listener.tree_exited.connect(func() -> void: self.unsubscribe(event_name, listener))
  if not listeners.has(event_name):
    listeners[event_name] = []
  listeners[event_name].append({"listener": listener, "method": method})

# Unregister a listener for an event
func unsubscribe(event_name: String, listener: Object, method : Variant = null) -> void:
  if listeners.has(event_name):
    listeners[event_name] = listeners[event_name].filter(func(entry : Dictionary) -> bool:
      # Unsubscribe only a specific method
      if method:
        return entry.listener != listener and entry.method != method
      # Unsubscribe listener from event
      else:
        return entry.listener != listener
    )
  else:
    print_debug("Unknown EventBus event: %s" % event_name)

# Emit an event to all registered listeners
func emit(event_name: String, data: Variant = null) -> void:
  if listeners.has(event_name):
    for entry : Dictionary in listeners[event_name]:
      # EventBus.emit("event", [array, of, values])
      if data is Array:
        # func _event(array, of, values):
        entry.method.callv(data)
      # EventBus.emit("event", value)
      elif data != null:
        # func _event(value):
        entry.method.call(data)
      # EventBus.emit("event")
      else:
        # func _event():
        entry.method.call()

Comments