0

Description

"## Introduction\r\n\r\nThe aim of this snippet is to offer a simple way to map physical events (mouse, keyboard, gamepad) to logical events (and identifier + activation flag).\r\n\r\n> [!NOTE]\r\n> One could easily modify the script to change identifier type from plain integer to, say, enumerate.\r\n\r\nAs always, I know that there's the whole `Input` API about action management and all, but instead of using its query approach (`is_action_*`), the following script will actively trigger a signal with the logical event identifier.\r\n\r\n> [!NOTE]\r\n> **Physical Event** is an event involving a physical interaction through a device, being keyboard, mouse or game controller.\r\n> **Logical Event** is an event that have a meaning gameplay-wise, like \"jumping\", \"interact\", etc.\r\n\r\n## Physical Event Resource\r\n\r\nBut first, we have to define a resource for physical event. This resource will allow describing an event, and a thread of alternative events.\r\n\r\n```gdscript\r\n@tool\r\nclass_name EventDescriptor\r\nextends Resource\r\n\r\nenum EventMedia {\r\n\tJOYSTICK,\r\n\tMOUSE,\r\n\tKEYBOARD,\r\n}\r\n\r\n@export var kind : EventMedia = EventMedia.KEYBOARD :\r\n\tset(v):\r\n\t\tkind = v\r\n\t\tnotify_property_list_changed()\r\n\r\n@export_subgroup(\"Activation\")\r\n@export_enum(\"Toggle:0\", \"Pressed:1\", \"Released:-1\") var activation : int = 0\r\n\r\n@export_subgroup(\"Joystick\", \"joy_\")\r\n@export var joy_button : JoyButton = JOY_BUTTON_INVALID\r\n@export var joy_button_value : float = 1.\r\n@export var joy_axis : JoyAxis = JOY_AXIS_INVALID\r\n@export_enum(\"Negative:-1\", \"Positive:1\", \"Both:0\") var joy_axis_range : int = 0\r\n\r\n@export_subgroup(\"Mouse\", \"mouse_\")\r\n@export var mouse_button : MouseButton = MOUSE_BUTTON_NONE\r\n@export var mouse_button_value : float = 1.\r\n\r\n@export_subgroup(\"Keyboard\", \"key_\")\r\n@export var key_shift_modifier : bool = false\r\n@export var key_ctrl_modifier : bool = false\r\n@export var key_alt_modifier : bool = false\r\n@export var key_meta_modifier : bool = false\r\n@export var key_code : Key = KEY_NONE\r\n@export var key_value : float = 1.\r\n@export_enum(\"Unspecified:0\", \"Left:-1\", \"Right:1\") var key_location : int = 0\r\n\r\n@export_subgroup(\"Alternate\")\r\n@export var alternate : EventDescriptor\r\n\r\nconst _FILTER_PREFIX : Dictionary[EventMedia, String] = {\r\n\tEventMedia.JOYSTICK : \"joy_\",\r\n\tEventMedia.MOUSE : \"mouse_\",\r\n\tEventMedia.KEYBOARD : \"key_\"\r\n}\r\n\r\nfunc _validate_property(property : Dictionary) -> void:\r\n\tvar pn : StringName = property.name\r\n\tif pn.contains(\"_\"):\r\n\t\tvar ok_prefix : String = _FILTER_PREFIX[kind]\r\n\t\tif not pn.begins_with(ok_prefix):\r\n\t\t\tproperty.usage = PROPERTY_USAGE_NO_EDITOR\r\n\r\n```\r\n\r\n### Properties\r\n\r\n* **kind** : Type of input (Joystick\/Mouse\/Keyboard)\r\n* **activation** : Determine when the action is triggered : When pressed\/not rest, when released\/at rest position, or both (toggle).\r\n* **joy_button** : Joystick button\r\n* **joy_button_value** : Value to send when the button is pressed\r\n* **joy_axis** : Joystick axis. Note that when using a joystick axis, the value sent is the value of the said axis.\r\n* **joy_axis_range** : Filter on joystick axis. The event can be associated to the positive, negative or both ranges.\r\n* **mouse_button** : Mouse button\r\n* **mouse_button_value** : Value to send when the mouse button is pressed\r\n* **key_xxx_modifier** : Modifiers to be affected to the key. If one of the modifier is released, the event will fire a release event IF the **activation** parameter is set to _toggle_ or _released_\r\n* **key_code** : Physical key code\r\n* **key_value** : Value to send when the key is pressed\r\n* **key_location** : Some keys can be located on left or right, such as modifiers keys (shift\/control). Here, you can choose to restrain to a certain location.\r\n* **alternate** : Alternative event descriptor that match the same event\r\n\r\n\r\n\r\n## Signal\r\n\r\nThe only emitted signal is `on_action(action_id : StringName, value : float)`. It is emitted each time a physical event (or alternative events) is triggered. It transmits the _logical event_ identifier (as a `StringName`) and if it is activated or not (can be seen as pressed\/released state). The `value` is `0` for \"not pressed\/unpressed\", else a value than can possibly correspond to the axis value or the value set in the event descriptor.\r\n\r\n## Parameters\r\n\r\n* **deadzone** : Your classic deadzone value for game controller axis. It permits to determine if an axis is in rest or active position (and thus possibly trigger an action).\r\n* **mapping** : A dictionary associating _logical event_ identifier to a _physical event_\r\n\r\n## Usage\r\n\r\nAttach this script to a node in your scene, provide an event mapping, and connect to the signal to be notified.\r\n\r\n> [!NOTE]\r\n> I've not added coded to aggregate axises values into `Vector2`, but it is pretty easy to make if you need it as all the information are there (see `last_joy_axis_values` )."

Screenshots

Main code

class_name SinglePlayerLogicalEventMapper
extends Node

signal on_action(action_id : StringName, value : float)

@export var deadzone : float = 0.1

@export var mapping : Dictionary[StringName, EventDescriptor] = {} :
	set(value) :
		mapping = value
		_remap()

var joybutton_press_event : Dictionary[JoyButton, StringName] = {}
var joybutton_release_event : Dictionary[JoyButton, StringName] = {}
var joybutton_value : Dictionary[JoyButton, float] = {}

var joyaxis_positive_press_event : Dictionary[JoyAxis, StringName] = {}
var joyaxis_positive_release_event : Dictionary[JoyAxis, StringName] = {}
var joyaxis_negative_press_event : Dictionary[JoyAxis, StringName] = {}
var joyaxis_negative_release_event : Dictionary[JoyAxis, StringName] = {}

var last_joy_axis_values : Array[float]

var mousebutton_press_event : Dictionary[MouseButton, StringName] = {}
var mousebutton_release_event : Dictionary[MouseButton, StringName] = {}
var mousebutton_value : Dictionary[MouseButton, float] = {}

var key_press_event : Dictionary[int, StringName] = {}
var key_release_event : Dictionary[int, StringName] = {}
var key_value : Dictionary[int, float] = {}

var key_left_press_event : Dictionary[int, StringName] = {}
var key_left_release_event : Dictionary[int, StringName] = {}
var key_left_value : Dictionary[int, float] = {}

var key_right_press_event : Dictionary[int, StringName] = {}
var key_right_release_event : Dictionary[int, StringName] = {}
var key_right_value : Dictionary[int, float] = {}


func _ready() -> void:
	last_joy_axis_values = []
	last_joy_axis_values.resize(JOY_AXIS_MAX)
	last_joy_axis_values.fill(0.)

func _remap() -> void:
	joybutton_press_event.clear()
	joybutton_release_event.clear()
	joybutton_value.clear()
	joyaxis_positive_press_event.clear()
	joyaxis_positive_release_event.clear()
	joyaxis_negative_press_event.clear()
	joyaxis_negative_release_event.clear()
	mousebutton_press_event.clear()
	mousebutton_release_event.clear()
	mousebutton_value.clear()
	key_press_event.clear()
	key_release_event.clear()
	key_value.clear()
	key_left_press_event.clear()
	key_left_release_event.clear()
	key_left_value.clear()
	key_right_press_event.clear()
	key_right_release_event.clear()
	key_right_value.clear()

	for m in mapping:
		var action_id : StringName = m
		var descriptor : EventDescriptor = mapping[action_id]
		while descriptor != null:
			_add_mapping(action_id, descriptor)
			descriptor = descriptor.alternate

func _add_axis_mapping(action_id : StringName, axis : JoyAxis, pressed : bool, filter : int) -> void:
	if pressed:
		if filter < 1:
			joyaxis_negative_press_event[axis] = action_id
		if filter > -1:
			joyaxis_positive_press_event[axis] = action_id
	else:
		if filter < 1:
			joyaxis_negative_release_event[axis] = action_id
		if filter > -1:
			joyaxis_positive_release_event[axis] = action_id

func _add_mapping(action_id : StringName, descriptor : EventDescriptor) -> void:
	var activation : int = descriptor.activation
	match descriptor.kind:
		EventDescriptor.EventMedia.JOYSTICK:
			if descriptor.joy_button != JOY_BUTTON_INVALID:
				var button : JoyButton = descriptor.joy_button
				joybutton_value[button] = descriptor.joy_button_value
				if activation < 1:
					joybutton_release_event[button] = action_id
				if activation > -1:
					joybutton_press_event[button] = action_id
			elif descriptor.joy_axis != JOY_AXIS_INVALID:
				var axis : JoyAxis = descriptor.joy_axis
				if activation < 1:
					_add_axis_mapping(action_id, axis, false, descriptor.joy_axis_range)
				if activation > -1:
					_add_axis_mapping(action_id, axis, true, descriptor.joy_axis_range)
		EventDescriptor.EventMedia.KEYBOARD:
			var key : int = descriptor.key_code
			if descriptor.key_alt_modifier: key += KEY_MASK_ALT
			if descriptor.key_ctrl_modifier: key += KEY_MASK_CTRL
			if descriptor.key_shift_modifier: key += KEY_MASK_SHIFT
			if descriptor.key_meta_modifier: key += KEY_MASK_META
			var release_map : Dictionary[int, StringName]; var press_map : Dictionary[int, StringName];
			var value_map : Dictionary[int, float]
			match descriptor.key_location:
				0:
					release_map = key_release_event;press_map = key_press_event;value_map = key_value
				-1:
					release_map = key_left_release_event;press_map = key_left_press_event;value_map = key_left_value
				_:
					release_map = key_right_release_event;press_map = key_right_press_event;value_map = key_right_value
			if activation < 1:
				release_map[key] = action_id
			if activation > -1:
				press_map[key] = action_id
			value_map[key] = descriptor.key_value
		EventDescriptor.EventMedia.MOUSE:
			if descriptor.mouse_button != MOUSE_BUTTON_NONE:
				var button : MouseButton = descriptor.mouse_button
				mousebutton_value[button] = descriptor.mouse_button_value
				if activation < 1:
					mousebutton_release_event[button] = action_id
				if activation > -1:
					mousebutton_press_event[button] = action_id
		_:
			pass

func _input(event : InputEvent) -> void:
	match event.get_class():
		"InputEventKey":
			var kev : InputEventKey = event as InputEventKey
			# kev.location
			if not kev.echo:
				var release_map : Dictionary[int, StringName]; var press_map : Dictionary[int, StringName];
				var value_map : Dictionary[int, float]
				match kev.location:
					KeyLocation.KEY_LOCATION_UNSPECIFIED:
						release_map = key_release_event;press_map = key_press_event;value_map = key_value
					KeyLocation.KEY_LOCATION_LEFT:
						release_map = key_left_release_event;press_map = key_left_press_event;value_map = key_left_value
					_:
						release_map = key_right_release_event;press_map = key_right_press_event;value_map = key_right_value
				var dict : Dictionary[int, StringName] = press_map if kev.pressed else release_map
				var key : int = kev.get_keycode_with_modifiers()
				if dict.has(key):
					on_action.emit(dict[key], value_map[key] if kev.pressed else 0.)
		"InputEventMouseButton":
			var mev : InputEventMouseButton = event as InputEventMouseButton
			var dict : Dictionary[MouseButton, StringName] = mousebutton_press_event if mev.pressed else mousebutton_release_event
			if dict.has(mev.button_index):
				on_action.emit(dict[mev.button_index], mousebutton_value[mev.button_index] if mev.pressed else 0.)
		"InputEventJoypadButton":
			var jev : InputEventJoypadButton = event as InputEventJoypadButton
			var dict : Dictionary[JoyButton, StringName] = joybutton_press_event if jev.pressed else joybutton_release_event
			if dict.has(jev.button_index):
				on_action.emit(dict[jev.button_index], joybutton_value[jev.button_index] if jev.pressed else 0.)
		"InputEventJoypadMotion":
			var jev : InputEventJoypadMotion = event as InputEventJoypadMotion
			var value : float = 0. if abs(jev.axis_value) < deadzone else jev.axis_value
			var activated : bool = not is_zero_approx(value)
			var last_activated : bool = not is_zero_approx(last_joy_axis_values[jev.axis])
			var press_dict : Dictionary[JoyAxis, StringName] = joyaxis_negative_press_event if last_joy_axis_values[jev.axis] < 0. else joyaxis_positive_press_event
			var release_dict : Dictionary[JoyAxis, StringName] = joyaxis_negative_release_event if last_joy_axis_values[jev.axis] < 0. else joyaxis_positive_release_event
			last_joy_axis_values[jev.axis] = value
			var dict : Dictionary[JoyAxis, StringName] = press_dict if activated else release_dict
			if dict.has(jev.axis) and (activated or last_activated):
				on_action.emit(dict[jev.axis], value)
		_:
			pass

Comments